; точка с запятой на этом языке - комментарий. У программеров Си\Джава взорван мозг
#NoTrayIcon
#NoEnv
SendMode Input
SetWorkingDir %A_scriptDir%

curr=%1%                                  ;без параметров, программа не запустится
if curr=
   ExitApp

FTPCommandFile = %A_scriptDir%\FTPCommands.txt   ;имя файла сценария
FTPLogFile = %A_scriptDir%\FTPLog.txt            ;имя логфайла
countf:=0
TSize:=0
FileDelete %FTPCommandFile%                      ;удаляем старые файлы 
FileDelete %FTPLogFile%                          ;на всякий случай
FileRead, conf, %A_scriptDir%\config.ini         ;считываем настройки в файл conf

n:=0
Loop, parse, conf,`n                             ;разбираем в цикле по строкам conf
{
     i:=0
     Loop, Parse, A_LoopField, |                 ;парсим по знаку |
     {                                           ;и заносим в двумерный массив всё
         con%n%%i% = %A_LoopField%               ;что там было
         i++
     }
     name:=con%n%0                               ;добавляем в цикле пункты меню. 
     Menu, PopUp, Add, %name%, Who               ;Who - процедура обработки выбора
     n++                                         ;меню
}
i:=0
n:=0

Menu, PopUp, Show                            ;и только теперь показываем меню.
                                             ;конечно не очень удобно что меню
                                             ;показывается не сразу, но по другому
                                             ;я не знаю как это сделать
return

Who:
{
  item:=A_THISMENUITEMPOS-1
  addr:=con%item%1
  login:=con%item%2
  pass:=con%item%3
  FileAppend, open %addr%`n, %FTPCommandFile%      ;пишем в файл сценария параметры
                                                   ;соединения на основе выбранного
  FileAppend, %login%`n, %FTPCommandFile%          ;меню
  FileAppend, %pass%`n, %FTPCommandFile%

  GoSub, Go                                        ;идём к основной процедуре
return
}

go:                                              ;эта процедура составляет запросы
{                                                ;в сценарии на передачу файлов
  FileAppend, binary`n, %FTPCommandFile%         ;двоичный режим передачи 
  prev=
  ToolTip Составляю список...
  Loop                                       ;этот цикл также отлавливает
  {                                             ;во входящих параметрах
                                                 ;нелогичные запросы и
                                                 ;догадывается что в пути 
                                                 ;файла были пробелы, поэтому
                                                 ;склеивает всё обратно
       curr:=%A_Index%             	                                        
       if not prev                          
       {                                        
           prev=%curr%
           continue
       }
       if(!InStr(curr, ":\") and (curr!="")) 
       {                                          ;во входящих параметрах нету ":\"?
           prev=%prev%%A_Space%%curr%             ;склеиваем
           continue
       }       
       FileGetAttrib, Attributes, %prev%
       IfInString, Attributes, D       ;если это папка, то идём в 
                                                   ;рекурсивную функцию
       GenFold(prev,FTPCommandFile,countf,TSize)        
       else
       {                                         ;если нет, то записываем файл
                                                  ;в сценарий
            FileAppend, put "%prev%"`n, %FTPCommandFile%
            FileGetSize, dsize, %prev%
            TSize += %dsize%        ;добавляем размер файла к общему
                                                  ;размеру всех файлов
            countf++                        ;увеличиваем счётчик файлов
       }    	   
        if curr =
		   break
        prev=%curr%
  }     
	
  FileAppend, quit, %FTPCommandFile%         ;добавляем в конец комманду выхода 
  SetFormat, float, 6.1
  TSize:=TSize/(1024*1024)
  ToolTIp Запускаю ftp.exe...                      
        	                                                ;запускаем ftp.exe
  Run %comspec% /c ftp.exe -s:"%FTPCommandFile%" >"%FTPLogFile%", ,Hide
  ToolTip
  ;если вы доверяете ftp и вам не нужен прогрессбар, то дальше можно не писать
  ;========================================================;создаём прогресбар
     CustomColor = 666666
     Gui, -Resize +LastFound +ToolWindow -Caption +AlwaysOnTop
     Gui, Color, %CustomColor%
                                  ;cFF9966 - меняйте цвет на какой хотите
     Gui, Add, Progress, x0 y0 w132 h15 cFF9966 Background666666 vMyProgLoadi
     GuiControl, , MyProgLoadi, 0
     Gui, Font, S7 c111111, Tahoma
     Gui, Add, Text, vMyMemLoadi BackGroundTrans x2 y2 w100 h15, 0/%Tsize%
     Gui, Show, h15 w132, MyProgLoadi	 ;===========================================================================
  countf2:=0
  TSize2:=0
  maybeexit:=0
  Loop     ;ожидаем пока запустится ftp.exe, если вдруг он ещё не запустился
  {
      Process, Exist, ftp.exe
      if(ErrorLevel = 0)
      {
         maybeexit++
         if(maybeexit>10)         ;наш порог терпения 5 секунд
         {
            MsgBox Чего-то ftp.exe долго не запускается`nЯ пожалуй завершусь.
            ExitApp
         }
         Sleep 500
         continue
      }
      break
  }
  Loop            ;этот цикл сканирует лог файл каждые 250 милисекунд и считывает
  {               ;сколько файлов уже передалось
      Process, Exist, ftp.exe     
      if((ErrorLevel = 0) or (countf2 >= countf))   ;выходим из цикла когда
      {                                      ;всё передалось или ftp.exe завершился
         Gui, Destroy
         FileRead, mfile, %FTPLogFile%
         IfNotInString,mfile,logged in  ;ftp.exe мог завершиться из-за
         {                                        ;того, что не смог присоедениться
             MsgBox, 36, Алярма, Не могу присоединиться.`nОткрыть Логфайл?
             IfMsgBox, Yes
                 Run, "%FTPLogFile%"
             break
         }
         SetFormat, float, 6.1
         ToolTIp Файлов: %countf%`nРазмер: %TSize% мб ;ToolTip о результатах
                                ;чтобы жёстко контролировать, вместо Tooltip
                                ;поставть MsgBox
         Sleep 2000
         ToolTip
         break
      }
      countf2:=0
      TSize2:=0
      FileRead, mfile, %FTPLogFile%
      Loop, Parse, mfile,`n            ;проверяем склько файлов уже передано
      {                                ;благодаря лог файлу
         If(InStr(A_LoopField, "ftp: "))
         {
            countf2++
            dsize2:=SubStr(A_LoopField, 6, InStr(A_LoopField," ", 0, 6)-1)
            TSize2 += %dsize2%
         }
      }
      GuiControl, 1: , MyProgLoadi, % (countf2*100)/countf ;двигаем прогрессбар
      SetFormat, float, 6.1
      TSize2:=TSize2/(1024*1024)
      GuiControl,Text , MyMemLoadi, %TSize2%/%TSize% мб
      Sleep 250
    }
    ExitApp
    return
}

GenFold(path,FTPCommandFile,ByRef countf,ByRef TSize) 
{                                         ;функция составления сценария для папок
    fold:=SubStr(path,InStr(path,"\",0,0)+1)
                                        ;создаём на удалённой машине папку с
                                        ;таким же названием и заходим в неё
                                        ;проходимся по всем файлам в этой папке
                                        ;папка - тоже файл (привет Юниксу)

    FileAppend, mkdir "%fold%"`n, %FTPCommandFile%
    FileAppend, cd "%fold%"`n, %FTPCommandFile%
    Loop, %path%\*, 1, 0
    {                                               
        FileGetAttrib, Attributes, %A_LOOPFILEFULLPATH%
        IfInString, Attributes, D                ;привет, мистер Рекурсия
            GenFold(A_LOOPFILEFULLPATH,FTPCommandFile,countf,TSize)
        else
        {
            FileAppend, put "%A_LOOPFILEFULLPATH%"`n, %FTPCommandFile%
            TSize += %A_LoopFileSize%
            countf++
        }
    }
    FileAppend, cd ..`n, %FTPCommandFile%
    return
}