войти зарегистрироваться

Ненормальное программирование whois

индекс
306,15

Мандельброт на .bat «for fun»

Вот эта картинка создана .bat файлом:



Многие не знают, но если приложить немного усилий, то командный процессор MS Windows становится способен на многое. В принципе, это обычный императивный язык программирования, немного со странностями, но именно они превращают программирование на нём в своеобразное развлечение. Многие действия, не предусмотренные в конструкции языка, надо придумать как имитировать, порой какими-то фантастическими способами.

Например, как сделать паузу на заданное количество секунд? Команда pause тут бессильна. В место неё паузу удобно организовать через ping.
Пауза на 5 секунд будет выглядеть вот так:
ping 127.0.0.1 -n 6 -w 1000 > nul

Вот как узнать, содержит ли строка подстроку? Опять же, на первый взгляд ничего подходящего нет. На помощь приходит замена подстроки в строке:
set string=SOME TEXT
if not "%string%"=="%string:TEXT=%" echo YES

Ещё на .bat можно организовать вычисления с плавающей точкой (изначально плавающая точка не поддерживается), распараллеленные вычисления, синхронизацию между «процессами», распараллеленное вычисление на нескольких компьютерах и т.п. Я как-то раз видел исходники полиморфного(!) вируса, который полностью написан на bat-файле :)

В общем, время от времени я пишу что-нибудь на .bat, не могу пройти мимо такого вызова :)
Cейчас выкладываю одну из своих работ: батник, который рендерит множество Мандельброта в bmp.

@echo off
set /a xPixels = 180
set /a yPixels = 120
set /a xStart = -22000
set /a yStart = -10000
set /a xSize = 32000
set /a ySize = 20000
set /a maxIter = 32
call ::make_bmp_header
 
set /a xStep = xSize/xPixels
set /a yStep = ySize/yPixels
 
set /a iy = 0
:iyLoop
 
  set /a ix = 0
  :ixLoop
 
    set /a x = xStart + ix * xStep
    set /a y = yStart + iy * yStep
    set /a x0 = x
    set /a y0 = y
 
    set /a iteration = 0
   
    :formula
      set /a xtemp = x*x/10000 - y*y/10000 + x0
      set /a y = 2*x*y/10000 + y0
      set /a x = xtemp
      set /a iteration+=1
 
      set /a dist = x*x/10000 + y*y/10000
      if [%iteration%]==[%maxIter%] goto breakFormula
    if /I %dist% LEQ 40000 goto :formula
    :breakFormula
   
    if [%iteration%]==[%maxIter%] (call :plot_black) else (call :plot_color %iteration%)
 
  set /a ix += 1
  if not [%ix%]==[%xPixels%] goto ixLoop
 
  set /a progress = yPixels - iy
  echo.%progress%
 
set /a iy += 1
if not [%iy%]==[%yPixels%] goto iyLoop
 
call ::make_bin
ren file$ result.bmp
mspaint result.bmp
exit/b
 
 
:plot_black
call :write_byte 0
call :write_byte 0
call :write_byte 0
exit/b
 
:plot_color
set /a rc=%1*5 + 32
set /a gc=%1*7 + 6
set /a bc=128 - (%1*3 + 4)
call :write_byte %rc%
call :write_byte %gc%
call :write_byte %bc%
exit/b
 
 
:make_bmp_header

set /a dataSize = xPixels * yPixels * 3 + 54
set /a dataSize0 = dataSize%%256
set /a dataSize1 = (dataSize/256)%%256
set /a dataSize2 = (dataSize/(256*256))%%256
set /a dataSize3 = (dataSize/(256*256*256))%%256
 
call :init_bin
 
call :write_byte 66
call :write_byte 77
 
call :write_byte 118
call :write_byte 56
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 54
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 40
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte %xPixels%
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte %yPixels%
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 1
call :write_byte 0
call :write_byte 24
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte %dataSize0%
call :write_byte %dataSize1%
call :write_byte %dataSize2%
call :write_byte %dataSize3%
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
call :write_byte 0
 
exit /b
 
 
:init_bin
echo.n file$>bin$
set /a addr=0x0100
call set "hstr=e "
call :write_word %addr%
set mustflush=0
exit /b
 
:write_byte
set /a a=%1
set hexs=0123456789ABCDEF
set /a a0=a/16
set /a a1=a%%16
call set res= %%hexs:~%a0%,1%%%%hexs:~%a1%,1%%
set hstr=%hstr%%res%
set /a addr+=1
set /a mod16=addr%%16
set mustflush=1
if not %mod16%==0 exit /b
echo.%hstr%>>bin$
call set "hstr=e "
call :write_word %addr%
set mustflush=0
exit /b
 
:write_word
set /a a=%1
set hexs=0123456789ABCDEF
set /a a0=a/4096
set /a a1=a/256%%16
set /a a2=a/16%%16
set /a a3=a%%16
call set res=%%hexs:~%a0%,1%%%%hexs:~%a1%,1%%%%hexs:~%a2%,1%%%%hexs:~%a3%,1%%
set hstr=%hstr%%res%
exit /b
 
:make_bin
if "%mustflush%"=="1" echo.%hstr%>>bin$
set /a filesz=addr-0x0100
echo.r cx>>bin$
set hstr=
call :write_word %filesz%
echo %hstr%>>bin$
echo.w>>bin$
echo.q>>bin$
debug<bin$
del bin$
exit /b


+200
14 июня 2009, 18:52
Imp5

комментарии (102)

  • Например, как сделать паузу на заданное количество секунд? Команда pause тут бессильна. В место неё паузу удобно организовать через ping.
    Пауза на 5 секунд будет выглядеть вот так:
    ping 127.0.0.1 -n 6 -w 1000 > nul

    Вот как узнать, содержит ли строка подстроку? Опять же, на первый взгляд ничего подходящего нет. На помощь приходит замена подстроки в строке:
    set string=SOME TEXT
    if not "%string%"=="%string:TEXT=%" echo YES


    да уж… прям через одно место это делается… но радует что есть люди которые умеют выйти из ситуации :)
    • Особенно интересно делается интерактивность =)
      Когда делал игру «сокобан», приходилось учитывать разные версии командной строки.
      • переходите на bash :)
        • а там нужно трудности преодолевать? =)
          • трудности — да, но не через одно место :)
        • сам по себе он не столько рулит (хотя конечно несравним с cmd), а вот вместе со стандартным набором консольных утилит… sed+awk это уже очень много.
          • sed, awk, grep, find… Этот список можно долго продолжать :)
    • таких людей зовут програмисты!=)
  • Код сходу непонятен, но чувствую, что круто! +
    • Да, сходу ничего непонятно, но создается впечатление, что если прочитать этот скрипт Пи раз задом наперед, то можно призвать дух Ады Лавлейс O_o
  • Больше всего понравилось: текст habracut`a
    (=
  • Гениально!!!
  • плюс вам, тов. Маньяк
  • Вы это сами всё? Тогда вы большой молодец. Плюс вам.
  • Черепашка тож много чего нарисовать может…
    • ага, Logo многие недооценивают…
      • «logo — это lisp без скобок», прочитал я в ZX-Review.
    • я еще и крестиком вышивать умею!
  • Это, конечно, не тетрис на sed, но всё равно круто.
    Никогда бы не подумал, что это возможно в принципе.
  • >паузу удобно организовать через ping

    Майкросовский подход :)
  • Мсье знает толк в извращениях…
  • я программировать начал с bat в досе на 286 в 96 году)) правда недолго) что-то делал интерактивное, но что б такое… я поражен. правда, похоже, за это время функциональность командного процессора несколько возросла.
    • а еще из извращений вспоминаются конфиги с навороченной логикой (менюшки там всякие, арт) для Quake 1 и 2 с их bind'ами и alias'ами :)
      • Ну не такие уж это и извращения. Часто батники как раз использовали для подобных вещей. Чтобы сделать некое подобие «интерфейса для секретарши».
  • А как такой код дебажить? Отладочными принтами, или есть возможность сделать это поудобнее?
    И как юзать плавающую точку?
    Да, это пожалуй самое оригинальное извращение из всех о которых я слышал =)
    • >А как такой код дебажить? Отладочными принтами, или есть возможность сделать это поудобнее?
      Да, отладочными echo.
      А ещё, если не делать @echo off, то можно видеть какие команды исполняются и с какими параметрами. Для удобства, этот вывод можно перенаправить в файл для дальнейшего изучения.

      >И как юзать плавающую точку?
      Надо написать функции для работы с плавающей точкой =)
      В этой програме я использовал фиксированную точку, 4 десятичных разряда для дробной части.
  • Когда программистам делать нечего :)
  • А вы не директор по ведущим разработкам Мелкософта? =)
  • мандельброт в 61 байт:
    tinyurl.com/llkbsd
    • Есть еще забавные варианты на JS (от 114 байт на всю страницу), результат в виде ASCII-арта.
  • Я как-то раз видел исходники полиморфного(!) вируса, который полностью написан на bat-файле

    Это не новость для посвящённых. В славные 90-е вирмейкеры куда больше изощрялись, чем сейчас. :)
    Интересующиеся могут полистать старые e-zines вирсцены.
    • Из российских я там заметил Chaos AD, Infected Voice, MoonBug.
      • О да! Infected Voice — помню, помню =)
        • еще Infected Moscow помню был один выпуск, а второго вроде бы так и не дождались…
          во были времена, когда натыкался на эти выпуски, приятно вспомнить.
  • О да! Infected Voice — помню, помню =)
    • Не туда ответил %|
  • С gamedev.ru

    Растеризация треугольника в консоли:
    www.everfall.com/paste/id.php?t5ht4mw6kvls

    Консольный сокобан:
    www.everfall.com/paste/id.php?szlzpnwtsftu
    • Это один и тот же автор.
    • «Pasted by Imp5»

      это автор топика видимо запостил)
      • да, это был я
      • Хех, вечером по запарке не заметил))
  • Под дос был криптор исполняемых файлов написанный на .bat Trap авторства Christoph Gabler, последние версии правда уже полностью на asm вроде перевел.
  • круто у Вас на работе. есть чем заняться ;)
    • это в свободное время.
      «programming for fun»
  • Ваша шайтан-программа грузит сеть весьма странным образом %)



    Батник был запущен с сетевой расшарки на другом компе. Временных файлов на расшарке я не увидел :)
    • кстати графики сетевой активности тоже можно попорбывать батниками рисовать. должно быть даже проще, но не так эффектно, конечно)
    • Учитывая, что автор интересовался Infected Voice, стоит прогнать машина антивирусом :))
    • дык это ж из-за ping-задержки наверное?
      • компы в пределах одного роутера, второй комп под линуксом. Обычно задержка очень маленькая. Скорее, дело действительно в механизме исполнения батника. Кстати, батник сразу предупредил, что будет использовать не текущий путь (в расшарке), а c:\windows\.
    • Вообще этот батник создаёт временные файлы в текущей папке.
      Ещё дело может быть в том, как cmd исполняет батники. Он их читает по командам (из-за этого батники можно менять в процессе исполнения)
    • временный файл создается, проверил (имя bin$)
  • Леша — ты опять забыл принять лекарство! =))
    • Изображение в посте напоминает как раз картику, которую психиатр показывает пациенту и спрашивает что вы на ней видите =)
      Мне напоминает повернутые пики или раздутые трефы
      • Это не картинка психиатра, там просто маленькая ящерка с выпотрошенными кишочками, которую ест ее мама
    • :)))))!
  • У меня эта хрень минут 5 гудела, может потому что виртуалка, но вряд ли. Так что батник для таких вещей — не самый лучший выбор))
    • у меня уже минут 20
      что я делаю не так?
      • Freeman85 не жалуется, он хвастается =)
        у меня на ноутбуке тоже где-то 20 минут работает.
        • Может и 20 минут, я как-то не засекал :) Просто говорю, что долго.
        • у меня работает 8 минут, идут цифры от 120 до нуля, потом выдает ошибку что файл с картинкой не найден, что я делаю не так? 0_о
          Батник в любой папке лежать может?
          • Батник должен быть в папке, которая свободна для записи.

            Посмотри, чтобы там уже не было result.bmp

            В строках
            set /a xPixels = 180
            set /a yPixels = 120
            замени разрешение на меньшее, например 8 на 8, чтобы не ждать результата долго.

            Есть ли у тебя mspaint.exe?

            Есть ли у тебя команда debug?
  • Когда я читаю вот такие стать, как ваша, я вдохновляюсь. Очень приятно читать настоящего хакера.

    Заметьте, ни одного заминусованного коммента к статье.
    • Ваш минусовать начали :D, поднял обратно до нуля.
      • Я предвидел — меня это не оскорбляет. Спасибо вам, но право не стоило.
  • Может кто в курсе, есть ли способ прервать выполнение батника для ввода данных и записи в переменную? Не считая сторонних программ которые записывают введенное значение в errolevel?
    • rem SETLOCAL ENABLEEXTENSIONS
      set /p var=Как Вас зовут?:
      echo Hello, %var%

      если не заработает, раскомментировать первую строчку
      • То что надо, спасибо :)
    • Если вам надо в определённом месте спросить что-то у пользователя, то вариант от kentaskis должен подойти.
      Если это нужно сделать в произвольный момент, то к сожалению, я не знаю простых способов.
  • Для пауз есть waitfor
    Ждем Doom на cmd скриптах :)
    • Да, начиная с Vista или 2003, waitfor есть в штатной комплектации.
  • раскрыть комментарий
    • Напишите Мандельброт на bash.
  • А мне вспомнился спектрум, как это не банально. И хоть мое счастливое детство прошло без детища синклера, но позже этот прекрасный компьютер чрезвычайно увлек меня в своем виртуальном (эмулируемом) воплощении. Многое тоже приходилось делать руками, а иногда и особым образом «удалять гланды». Как первому (операции с плавающей точкой, тригонометрия через ряды, умножение с делением, которые Z80 не поддерживал), так и второму (нестандартные видеорежимы, вывод на экран блоками по 8х8, внутри которых можно использовать лишь 2 различных цвета, 3d на такой простенькой машинке) можно было обучиться, читая ZX-прессу, дискмаги и газеты. Среди прочих равных выделялся журнал ZX Format. В нем всегда можно было найти статейку-другую о программировании для speccy. Эх…
    • … и тут все должны прослезиться?
  • Такими темпами скоро варкрафт на бат перепишут )))
  • 20 минут и файл размером 180x120px :) Хорошо повеселили
  • пару секунд и



    Правда в Linux и с помощью специализированной программы Fraqtive.

    С помощью пинга локалхоста задержки делать + (не могу пока).
  • В универе в курсе Синергетики такие изображения назывались Фракталы. Есть также спец. программы, которые их строят.
  • Например, как сделать паузу на заданное количество секунд?
    В Windows7, не знаю как в Vista наконецто добавили
  • Извиняюсь за отрывок, случайно отправил
    Examples:
    TIMEOUT /?
    TIMEOUT /T 10
    TIMEOUT /T 300 /NOBREAK
    TIMEOUT /T -1

    Parameter List:
    /T timeout Specifies the number of seconds to wait.
    Valid range is -1 to 99999 seconds.

    /NOBREAK Ignore key presses and wait specified time.

    /? Displays this help message.

    NOTE: A timeout value of -1 means to wait indefinitely for a key press.
  • а я уж думал, что щас картинка 20 на 20 тыс. px вылезет…
  • Теперь осталось написать на .bat-файлах веб-сервер
  • Люди знают толк в извращениях
  • класс :)
    вспоминаю молодость :)
Только авторизованные пользователи могут оставлять комментарии. Авторизуйтесь, пожалуйста.